Code Snippets for Developers

[joe13]

Code Snippets for Developers

This page is intended to help theme developers add advanced features to their themes, and to help others start creating themes.

If there's something you'd like to know, or you want to submit a snippet to others, please contact me by PM.

INDEX:

• Getting Message Counts
• Haptic Feedback
• Reverse Playback
• Fading MovieClips in/out
• Changing Text colors
• Displaying the Time & Date
• Create a scrollable list menu
• Open Applications or Nyx Menu pages
• Displaying the 'Touch Ring' animation
• Launching the Dialpad
• Setting the current profile
• Getting the current profile
• Detecting the Headset status
• Getting the names of the user defined profiles
• Getting the current battery level
• iPhone style lock slider
• Grid layout menu
• 'GridLock' Theme - combination of lock slider and grid menu in a very simple theme
• Grid Desktop - grid layout menu with move-able icons
• Sliding Screens
• Developing Flash for Mobile Devices
• Loading/Saving data using fscommand2
  

[joe13]

function getMessages() {
    _root.GetMessageCount(); //Call to Nyx - updates message counts
    var inboxCount:Number = _root.inboxCount;
    var newInboxCount:Number = _root.newInboxCount;
    var draftCount:Number = _root.draftCount;
    var sentCount:Number = _root.sentCount;
    var outboxCount:Number = _root.outboxCount;
    //Check to see if message counts have loaded yet
    //it can take a few seconds at phone startup
    if (isNaN(inboxCount)) {
        inboxCount =  0;
        newInboxCount = 0;
        draftCount = 0;
        sentCount = 0;
        outboxCount = 0;
    }
    
    //Now do what you like with the inboxCount, newInboxCount
    //draftCount, sentCount and outboxCount variables
    //You probably want to update you messages counts every 
    //5 seconds or so.
}

Example Usage:
Simply call

getMessages();

everytime you want to update your message counters.
At the end of the function you would normally add a few statements to put the message counts into text-boxes, such as

    //put this at the end of the getMessages function
    my_text.text = newInboxCount + "/" + inboxCount

would update the 'my_text' text-box with the number of new messages and total messages in the users inbox.

You cannot get message counts for e-mails.
Also it is not possible to retrieve the number of missed calls etc.

[joe13]

platform.touch_sound();

This simple snippet makes the screen vibrate when called - generally used with the onPress action of buttons.

Example Usage:

my_btn.onPress = function() {
    platform.touch_sound();
}

Makes the button with the instance name 'my_btn' vibrate when pressed on the phone.

[joe13]

Want to play an animation, but in reverse? Add this code to your theme:

MovieClip.prototype.reversePlay = function(frameNum:Number) {
    if (frameNum > 0 && this._currentframe > 1) {
        if (this.revTimer_mc instanceof MovieClip) {
            this.revTimer_mc.removeMovieClip();
        }
        this.createEmptyMovieClip("revTimer_mc", this.getNextHighestDepth());
        
        var ref:MovieClip = this;
        var iCount:Number = 0;
        this.revTimer_mc.onEnterFrame = function() {
            ref.prevFrame();
            iCount++;
            if (iCount >= frameNum || ref._currentframe == 1) {
                delete this.onEnterFrame;
            }
        }
    }
}

Example Usage:

target_mc.reversePlay(5);

This makes the MovieClip 'target_mc' play backwards for 5 frames

[joe13]

Put the following code in the first frame of your theme:

MovieClip.prototype.fade = function(startAlpha:Number, endAlpha:Number, duration:Number) {
    if (duration > 0) {
        if (this.fadeTimer_mc instanceof MovieClip) {
            this.fadeTimer_mc.removeMovieClip();
        }
        this.createEmptyMovieClip("fadeTimer_mc", this.getNextHighestDepth());
        
        var alphaIncr:Number = Math.round((endAlpha - startAlpha)/duration);
        var ref:MovieClip = this;
        this._alpha = startAlpha; // Set initial alpha
        
        var iCount:Number = 0;
        this.fadeTimer_mc.onEnterFrame = function() {
            ref._alpha += alphaIncr;
            iCount++;
            if (iCount >= duration) {
                ref._alpha = endAlpha;
                delete this.onEnterFrame;
            }
        }
    }
}

Example Usage:

target_mc.fade(0, 100, 5);

Fades the MovieClip 'target_mc' from alpha=0 to alpha=100 in 5 frames

[joe13]

If you want to just change the color of a text-box, use:

my_text.textColor = myColor;

//myColor needs to be a hex-decimal number in the
//format 0xNNNNNN (where N are the color numbers)

Remember to give your text-box an instance name so that you can reference it in your code.

Example Usage:

my_text.textColor = 0xFFFFFF; //White
my_text.textColor = 0x000000; //Black

This changes the colour of the text-box with the instance name 'my_text' to white and then black. Hex-decimal codes for colours can be found in most image editing programs.

[joe13]

Use a function like the following to create a clock (you can use more, or less details in your application):

function updateClock() {
    var currentDate:Date = new Date(); //Current Date-Time
    
    var dateNum:Number = currentDate.getDate(); //Date eg 21st
    //Day 0 - 6, 0 = Sunday, 1 = Monday ...
    var dayNum:Number = currentDate.getDay();
    var dayArr:Array = new Array("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");

    var dayStr:String = dayArr[dayNum];

    date_tf.text = dateNum;
    day_tf.text = dayStr;

    //You need 2 dynamic text-boxes with the instance
    //name 'date_tf' & 'day_tf'

    //You can also get the time, year & month from the date object
    var hourNum:Number = currentDate.getHours(); //Hours
    var minNum:Number = currentDate.getMinutes(); //Minutes
    var monthNum:Number = currentDate.getMonth(); //Month 0 - 11
    var yearNum:Number = currentDate.getFullYear();
}

Example Usage:
You need 2 dynamic text-boxes with the instance name 'date_tf' & 'day_tf', also
copy the updateClock method from above into your code

var clockInterval:Number;

function startClock() {
    //Update clock to begin with
    updateClock();

    var refreshTime:Number = 1000; //1 second
    clockInterval = setInterval(updateClock, refreshTime);

    //Updates clock every second
}

function stopClock() {
    clearInterval(clockInterval);
}

//Now let's start the clock
startClock();

[joe13]

Source code & sample SWF are attached.

[joe13]

Use the following function below with either a Dep or Id value (you can find these in LGAPP/Media/swf/en-UK.xml) to launch a menu page or application.

function eventCall(dep:String, id:String) {
    if (id == undefined || id == "") {
        //No id - open menu Nyx page
        platform.setMenuOn();
        _root.idleQuick = true;
        _root.QuickSet(dep);
    } else {
        //Open application
        platform.launch_module(id);
    }
};

Example usage:

eventCall("", "0x27e00000"); // Open Inbox
eventCall("3,1,1", ""); //Open browser menu page

[joe13]

Use the following two functions to show & hide the default style 'Touch Ring' animation:

To show it at a location xPos,yPos with a scaling factor scalePercent (100 is original size):

show_pressAni(xPos:Number, yPos:Number, scalePercent:Number);

To hide the touch ring animation, simply call:

out_pressAni();

Example Usage:

my_btn.onPress = function() {
    show_pressAni(120, 200, 50);
}

my_btn.onReleaseOutside = function() {
    out_pressAni();
}

my_btn.onRelease = function() {
    out_pressAni();
    //Do something else
}

This will show the touch ring animation at the center of the screen (120, 200) at half its original size when the button "my_btn" is pressed. It then hides the animation when the button is released.